excelvba自定义函数(vba自定义函数参数说明)

导语：一个例子入门VBA自定义Excel函数（多值查找）

我们知道，Excel VBA除了定义过程以外，还可以自定义函数。

一个例子：

定义一个多值查找函数look()。（Excel有一个vlookup函数，可以实现单值查找，也就是找到每一个匹配的值。）

自定义look多值查找函数功能：

在第一参数“区域”所代表的列中查找第二参数“查找值”的值，然后根据第三参数“列”的值确定返回值所在列的值

如果有找到多个值，那么由第四参数决定返回第几个值

忽略第三参数时表示默认值是为2，即返回“区域”右边一列的值

忽略第四参数时表示默认值1，即返回第一个值

使用函数可参考以下公式：=look(E$2,B$1:C$12,2,ROW(A1))

1 显示“开发工具”选项卡

Office按钮→Excel选项→“常用”选项卡→勾选：在功能区显示“开发工具”选项卡；

2 启用“宏”

“开发工具”选项卡→宏安全性→勾选：启用所有宏；

3 复制上述代码；

4 “开发工具”选项卡→Visual Basic→插入→模块→在代码窗口输入如下代码：

代码如下：

Function look(查找值 As String, 区域 As Range, Optional 列 As Integer = 2, Optional 索引号 As Integer = 1) As String

'确定函数Look，类型为String。包括四个参数，前两个为必选参数，后两个为可选参数

Dim i As Long, cell As Range, Str As String

With 区域.Columns(1) '引用区域的第一列

'如果引用区域第一个单元格等于查找的对象，那么将该单元格赋予变量Cell。否则使用Find方法查找，将找到的单元格赋予变量Cell

If .Cells(1) = 查找值 Then Set cell = .Cells(1) Else Set cell = .Find(查找值, LookIn:=xlValues, lookat:=xlWhole)

If Not cell Is Nothing Then '如果找到

Str = cell.Address '记录单元格地址

Do '通过循环语句继续查找

i = i + 1 '累加变量，表示符合条件的个数

'如果变量等于最后一个参数，那么将查找到的单元格右边的值赋予Look函数

If i = 索引号 Then look = cell.Offset(0, 列 - 1): Exit Function

Set cell = 区域.Find(查找值, cell, , xlWhole) '查找下一个

'如果找到的目标单元格地址不等于第一次找到的单元格的地址就继续查找

Loop While cell.Address <> Str

Else

look = "" '如果找不到则直接返回空白

End If

End With

End Function

5 保存自定义函数

文件→另存为→保存类型：Excel启用宏的工作簿→确定；

6 使用自定义函数

6.1 使用函数的数据源

如下表所示：对应的成品有多个部件，需要要通过成品编码去查询有哪些部件，Excel的Vlookup函数不能满足需要，而上述定义的自定义函数可以达到上述的要求。

6.2 输入自定义函数look

如C2==look(A$2,基础资料!A$1:D$671,2,ROW(A1))

通过A$2的值去查找上述工作表“基础资料”对应区域对应列的第n个值；

如下表所示，默认查找15个值，每一个值对应5列的数据；

6.3 利用设置好的自定义函数进行查询

在A$2位置输入需要查询的成品编码，即可以查询到对应的数据。

-End-

本文内容由小婷整理编辑！